
ReqAI is an extensible Elixir client for AI APIs, built on Req.
{:ok, %Req.Response{}, %{"output" => [%{"content" => [content]}]}} =
  ReqAI.generate(ReqAI.Provider.OpenAI, 
    model: "gpt-5.4-mini",
    input: "Say hello"
  )

IO.puts(content["text"])
See the Getting Started guide for configuration and usage examples.
Features
	Generate and stream with one calling convention, using each provider's request and response formats.
	Built-in adapters for Anthropic, OpenAI, Gemini, OpenRouter, and TypeSafe. Add custom adapters with the Provider behaviour.
	Telemetry for request lifecycle, duration, token usage, and time to first chunk. Customize metadata with the Telemetry behaviour.
	Configure authentication, retries, timeouts, and testing through Req.
	Optional translators for your own request, response, error, and event shapes.

Installation
Add ReqAI to your dependencies in mix.exs:
{:req_ai, ">= 0.0.0"}
Requires Elixir 1.18 or later and Req 0.8.0 or later.


  

    Getting Started

ReqAI provides a common calling convention on top of AI provider APIs. Pass a provider module or a configured ReqAI.Provider to ReqAI.generate/2 or ReqAI.stream/4.
Req compatibility
ReqAI depends on Req 0.8 and requires Elixir 1.18 or later.
Configuring API keys
To call any provider, you'll need to configure it with an API key. You have two options.
First, you can use the application configuration. In config/runtime.exs:
config :req_ai, :providers, [
  {ReqAI.Provider.OpenAI, req: [auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")}]}
]
Second, you can configure a provider directly in code. This is useful if you need to switch keys dynamically, or when working in scripts or without a Mix project:
provider =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    req: [auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")}]
  )

ReqAI.generate(provider, request)
This guide assumes API keys are configured in the application configuration. Learn more in Provider configuration.
Generate a response
At its simplest, ReqAI provides everything except an API key. The below example calls OpenAI:
{:ok, %Req.Response{}, %{"output" => [%{"content" => [content]}]}} =
  ReqAI.generate(ReqAI.Provider.OpenAI,
    model: "gpt-5.4-mini",
    input: "Say hello"
  )

IO.puts(content["text"])
Notice the request body (the model and input keyword list) and response body are the same format as the underlying provider, in this case, OpenAI's Responses API. By default, the request and response bodies will always match that of the underlying provider's API.
Here's another example, this time using Anthropic's Messages API:
{:ok, %Req.Response{}, %{"content" => [content]}} =
  ReqAI.generate(ReqAI.Provider.Anthropic,
    model: "claude-opus-5-5",
    max_tokens: 256,
    messages: [%{role: "user", content: "Say hello"}]
  )

IO.puts(content["text"])
ReqAI intentionally does not standardize provider request or response bodies. Instead, the code maps directly to the underlying provider API. If desired, you can bring your own request and response body abstraction by configuring a translator.
Stream a response
Streaming is supported using ReqAI.stream/4. For example, we can stream a haiku:
request = %{
  model: "gpt-5.4-mini",
  input: "Write a Haiku"
}

{:ok, %Req.Response{}, haiku} =
  ReqAI.stream(ReqAI.Provider.OpenAI, request, [], fn event, %Req.Response{}, iodata ->
    case event do
      %{event: "response.output_text.delta", data: %{"delta" => delta}} ->
        IO.write(delta)
        {:cont, [iodata, delta]}

      %{event: "response.completed", data: %{"response" => %{"usage" => usage}}} ->
        IO.write("\n\n=== Total tokens: #{usage["total_tokens"]}\n")
        {:halt, IO.iodata_to_binary(iodata)}

      _ ->
        {:cont, iodata}
    end
  end)

IO.puts(haiku)
Streaming takes an accum and callback function. The function is passed the decoded event, the %Req.Response{}, and the accum (same as the underlying Req.stream/4).
ReqAI uses each provider's request and event formats. Built-in adapters convert keyword request bodies to maps. Streaming-capable adapters override the body's stream field: false for ReqAI.generate/2, true for ReqAI.stream/4. For SSE streams, they decode JSON payloads in the event's :data field and discard ping events, empty data, and [DONE] markers.
Return values
The examples above match successful responses for brevity. Real application code will want to handle both success and failure cases.
case ReqAI.generate(provider, request) do
  {:ok, _response, body} ->
    {:ok, body}

  {:error, response, body} ->
    {:error, {:http, response.status, body}}

  {:error, exception} ->
    {:error, {:request, Exception.message(exception)}}
end
There are two main differences here from Req's return values:
	Only 2xx responses are returned with :ok tuples. A 4xx or 5xx would be an :error tuple (the second branch above).
	The :ok and :error tuples (non-exceptional) return a third argument. By default, it's the body of the %Req.Response{} struct. If using translators, it would be the result of calling one of the translator behaviour callbacks.

An HTTP error, such as a 401 or 429, preserves the response and provider error body. A returned transport or decoding error carries an exception instead.
Streaming failures can include a partial response and the accumulator collected so far:
case ReqAI.stream(provider, request, [], fun) do
  {:ok, response, chunks} ->
    text = chunks |> Enum.reverse() |> IO.iodata_to_binary()
    {:ok, text, response.headers}

  {:error, response, body} ->
    {:error, {:http, response.status, body}}

  {:error, exception, response, chunks} ->
    partial_text = chunks |> Enum.reverse() |> IO.iodata_to_binary()
    {:error, {:request, Exception.message(exception), response, partial_text}}
end
On a non-successful HTTP response, ReqAI buffers the error body instead of passing it to your callback, decoding JSON when possible. On a returned transport or decoding failure, response may be nil, and chunks contains any text already collected.
These tuples describe HTTP and request outcomes. Providers may also report failures inside a successful HTTP response or streamed event. Inspect their native status fields and error events when your application needs to distinguish those outcomes; the text-only callbacks above ignore non-text events. Exceptions raised by your callbacks propagate to the caller.
Retries and timeouts are controlled by Req through :req. See ReqAI.generate/2 and ReqAI.stream/4 for the complete return contracts.


  

    Provider configuration

ReqAI.Provider.new/2 accepts a provider module and options. HTTP configuration goes under :req: authentication, headers, timeouts, retries, and other options supported by Req.new/2.
You can set application defaults, supply options when creating a provider, or combine the two.
Application configuration
Set shared HTTP options for each provider in config/config.exs:
import Config

config :req_ai, :providers, [
  {ReqAI.Provider.OpenAI, req: [receive_timeout: 60_000]},
  {ReqAI.Provider.Anthropic, req: [receive_timeout: 60_000]}
]
Read credentials at application startup in config/runtime.exs:
import Config

config :req_ai, :providers, [
  {ReqAI.Provider.OpenAI,
   req: [auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")}]},
  {ReqAI.Provider.Anthropic,
   req: [headers: [{"x-api-key", System.fetch_env!("ANTHROPIC_API_KEY")}]]}
]
Elixir merges these keyword configurations, so the runtime credentials are combined with the timeouts from config/config.exs.
Pass provider modules directly to use those defaults:
ReqAI.generate(ReqAI.Provider.OpenAI, model: "gpt-5.4-mini", input: "Say hello")
Both ReqAI.generate/2 and ReqAI.stream/4 accept modules and call ReqAI.Provider.new/2 with no additional options on every invocation. This reads the current application configuration each time. Only :req options are read from application configuration; translators, custom telemetry, telemetry metadata, and extra provider options require explicit construction.
You can also create and reuse providers to retain the configuration read at construction time:
openai = ReqAI.Provider.new(ReqAI.Provider.OpenAI)
anthropic = ReqAI.Provider.new(ReqAI.Provider.Anthropic)
The built-in adapters supply their API endpoints. The Anthropic adapter also supplies the anthropic-version: 2023-06-01 header unless you override it.
Configure a provider directly
You can instead pass the same HTTP options directly to ReqAI.Provider.new/2, without application configuration:
openai =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    req: [
      auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")},
      receive_timeout: 60_000
    ]
  )

anthropic =
  ReqAI.Provider.new(ReqAI.Provider.Anthropic,
    req: [
      headers: [{"x-api-key", System.fetch_env!("ANTHROPIC_API_KEY")}],
      receive_timeout: 60_000
    ]
  )
ReqAI does not automatically read API key environment variables. These examples explicitly read them and pass their values to Req.
Override request configuration
Options passed when creating a provider take precedence over its application defaults. For example, keep the configured credentials but use a longer receive timeout and disable retries:
openai =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    req: [receive_timeout: 120_000, retry: false]
  )
Options are merged by Req, e.g., explicitly supplied headers replace the configured value for that name.
To use an API-compatible proxy, override :base_url with the full endpoint, including its path:
proxied_openai =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    req: [base_url: "https://llm-proxy.example.com/v1/responses"]
  )
HTTP options and body parameters
Put HTTP options under :req when creating the provider. Put model names and other API body parameters in the request passed to ReqAI.generate/2 or ReqAI.stream/4.
Arbitrary options can be passed to ReqAI.Provider.new/2. These will later be passed to the provider, telemetry, and translator modules when their callbacks are invoked. This enables clients to supply runtime configuration when desired.


  

    Custom providers

To support a custom provider in your application, implement the ReqAI.Provider behaviour. This guide demonstrates how to do so using OpenAI's Chat Completions API as an example.
Implement the provider
Create lib/my_app/providers/chat_completions.ex:
defmodule MyApp.Providers.ChatCompletions do
  @behaviour ReqAI.Provider

  @impl true
  def build(req, request, _opts) do
    body = request |> Map.new() |> Map.drop([:stream, "stream"]) |> Map.put(:stream, false)

    req
    |> Req.Request.put_new_option(:base_url, "https://api.openai.com/v1/chat/completions")
    |> Req.merge(method: :post, json: body)
  end
end
build/3 receives the configured Req.Request, the request body, and provider options. It returns a request for ReqAI to execute. Extend the supplied req to preserve the caller's HTTP options.
Map.new/1 accepts a map or keyword list and ensures the top-level JSON value is an object. This allows clients to pass a keyword list or map for convenience.
put_new_option/3 supplies a default endpoint while allowing callers to override :base_url. Allowing these overrides is helpful in cases where you may want to dynamically point to different services that are compatible with the API, in this case, the Chat Completions format.
In this example, the provider forces stream: false, meaning this provider is unable to stream. We'll see how to add streaming support below.
Call the provider
Configure authentication, then pass a model and messages to ReqAI.generate/2:
provider =
  ReqAI.Provider.new(MyApp.Providers.ChatCompletions,
    req: [auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")}]
  )

request = %{
  model: "gpt-5.4-mini",
  messages: [%{role: "user", content: "Say hello"}]
}

{:ok, _response, body} = ReqAI.generate(provider, request)

[%{"message" => %{"content" => text}}] = body["choices"]
IO.puts(text)
Req decodes the JSON response into maps with string keys. This text-only example reads the single returned choice.
The example matches a successful response. ReqAI returns {:error, response, body} for non-2xx responses and {:error, exception} for errors returned by Req. See Return values for error handling.
Custom providers use the same application configuration as built-in providers. Once HTTP options are configured under MyApp.Providers.ChatCompletions, you can pass that module directly to ReqAI.generate/2.
ReqAI emits lifecycle telemetry without additional callbacks. To add provider, model, or token-usage attributes, implement ReqAI.Telemetry on the provider or configure a separate extractor. See the telemetry guide.
Add streaming
Update build/3 to use opts[:stream], which ReqAI sets to false for generation and true for streaming. Add decode_event/3 to decode the SSE payloads. The complete provider becomes:
defmodule MyApp.Providers.ChatCompletions do
  @behaviour ReqAI.Provider

  @impl true
  def build(req, request, opts) do
    body = request |> Map.new() |> Map.drop([:stream, "stream"]) |> Map.put(:stream, opts[:stream])

    req
    |> Req.Request.put_new_option(:base_url, "https://api.openai.com/v1/chat/completions")
    |> Req.merge(method: :post, json: body)
  end

  @impl true
  def decode_event(%{data: data}, _response, _opts) when data in ["", "[DONE]"] do
    []
  end

  def decode_event(%{data: data} = event, _response, _opts) do
    [%{event | data: JSON.decode!(data)}]
  end
end
Req handles SSE framing and passes event maps to the decoder. The decoder returns a list: [] discards empty data and the [DONE] marker; [event] delivers one event to the consumer. Here, JSON is decoded in :data, preserving the surrounding SSE fields. Invalid JSON raises and propagates to the caller.
Using the same provider and request from above, collect text from Chat Completions' delta.content field:
{:ok, _response, chunks} =
  ReqAI.stream(provider, request, [], fn event, _response, chunks ->
    case event do
      %{data: %{"choices" => [%{"delta" => %{"content" => text}}]}}
      when is_binary(text) ->
        IO.write(text)
        {:cont, [text | chunks]}

      _ ->
        {:cont, chunks}
    end
  end)

text = chunks |> Enum.reverse() |> IO.iodata_to_binary()
The callback returns {:cont, chunks} to continue, or can return {:halt, chunks} to stop early. This example collects text for a single choice and ignores other events, including tool calls and provider error payloads. The accumulated text is returned separately from the HTTP response; ReqAI does not assemble a completed Chat Completions response body.
Skip decoding unwanted events
decode_event/3 can discard events before calling JSON.decode!/1, avoiding JSON parsing work for events you do not need. For an API that sends named SSE events, add a clause before the JSON-decoding clause. For example, to skip ping events:
def decode_event(%{event: "ping"}, _response, _opts), do: []
This works when you can identify the event from its SSE fields without inspecting the JSON payload. Chat Completions uses data-only events, so filtering by fields inside its JSON still requires decoding; the example above already skips its [DONE] marker before decoding.


  

    Translators

Applications sometimes need interchangeable models. The same feature should work with e.g. OpenAI or Anthropic without changing the calling code. ReqAI doesn't try to unify request and response bodies across providers. A generic library can't know which differences matter to your application or how to represent them. Only your application does.
Instead, you bring your own abstraction. Configure a ReqAI.Translator on the provider, and ReqAI calls your callbacks at the request and response boundaries to translate between your shape and the provider's.
A simple shared interface
Suppose an application only needs to send a prompt string and receive a text string. The provider configuration selects the model:
{:ok, response, text} = ReqAI.generate(provider, "Explain recursion in one sentence.")
Implement request/2 to turn the prompt into a provider request, and response/2 to extract text from a successful HTTP response.
Translate OpenAI Responses
OpenAI's Responses API accepts a string as input and returns text within its output items:
defmodule MyApp.OpenAITranslator do
  @behaviour ReqAI.Translator

  @impl true
  def request(prompt, opts) when is_binary(prompt) do
    %{model: Keyword.fetch!(opts, :model), input: prompt}
  end

  @impl true
  def response(%Req.Response{body: body}, _opts) do
    [%{"content" => [%{"type" => "output_text", "text" => text}]}] = body["output"]
    text
  end
end
Translate Anthropic Messages
Anthropic's Messages API takes a messages list and requires max_tokens. Its response contains a list of content blocks:
defmodule MyApp.AnthropicTranslator do
  @behaviour ReqAI.Translator

  @impl true
  def request(prompt, opts) when is_binary(prompt) do
    %{
      model: Keyword.fetch!(opts, :model),
      max_tokens: Keyword.fetch!(opts, :max_tokens),
      messages: [%{role: "user", content: prompt}]
    }
  end

  @impl true
  def response(%Req.Response{body: body}, _opts) do
    [%{"type" => "text", "text" => text}] = body["content"]
    text
  end
end
Handle success and errors
response/2 is only invoked for successful HTTP responses, where these text-generation examples expect text content. For brevity, they assume a single text block and a single output item.
For non-2xx responses, ReqAI calls error/2 instead. Add this callback to either translator to return the HTTP status alongside the provider's error details:
@impl true
def error(%Req.Response{status: status, body: body}, _opts) do
  %{status: status, details: body}
end
For example, a 401 response returns {:error, response, %{status: 401, details: body}}. Without error/2, the third element is the original response body. Transport errors bypass this callback.
Switch providers
Configure each provider with its translator and model. This example assumes API keys are already configured:
openai =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    translator: MyApp.OpenAITranslator,
    model: "gpt-5.4-mini"
  )

anthropic =
  ReqAI.Provider.new(ReqAI.Provider.Anthropic,
    translator: MyApp.AnthropicTranslator,
    model: "claude-sonnet-4-6",
    max_tokens: 256
  )

# For example, maybe you choose a provider based on your user's preferences.
provider = select_provider_for_user(user, [openai, anthropic])

{:ok, response, text} = ReqAI.generate(provider, "Explain recursion in one sentence.")
IO.puts(text)
This example is deliberately simple. Real applications may need to translate conversation history, tool calls, structured output, and provider-specific errors. Translators let you keep those differences in one place while the rest of your application uses the interface it needs.
Translate only what you need
All translator callbacks are optional:
	Callback	Purpose	Default when omitted
	request/2	Convert application input to a provider request	Pass input through
	response/2	Produce the third tuple element for a successful generate/2 call	response.body
	error/2	Produce the third tuple element for a non-2xx response	response.body
	event/3	Convert each decoded stream event before the consumer callback	Pass the event through

Without error/2 or event/3, HTTP error bodies and streaming events keep their native formats. response/2 is not called for streams; the consumer's accumulator is the result. Errors returned by Req bypass response and error translation, and exceptions raised by translators propagate to the caller.


  

    Telemetry

ReqAI emits telemetry by default. Anthropic, OpenAI, Gemini, and OpenRouter use the same event names and add metadata from their native requests and responses.
Default events
ReqAI.generate/2 uses the prefix [:req_ai, :generate]; ReqAI.stream/4 uses [:req_ai, :stream].
	Event suffix	When emitted	Measurements
	:start	Before the HTTP request	:system_time, :monotonic_time
	:stop	When the call returns, including HTTP and transport errors or an early stream halt	:duration, :monotonic_time; streams also include :time_to_first_chunk when available
	:exception	When code inside the telemetry span raises, throws, or exits	:duration, :monotonic_time

For example, a completed generation emits [:req_ai, :generate, :stop]. Attach handlers with :telemetry.attach/4 or :telemetry.attach_many/4 to consume these events. There is no separate telemetry event for each streamed chunk.
Time measurements use native units. Convert a duration to milliseconds with System.convert_time_unit(duration, :native, :millisecond). Time to first chunk measures the first Req stream callback for a 2xx response, even if the provider discards that event as protocol-only.
Request translation and request construction happen before the span, so failures there do not emit these events. Exception metadata includes :kind, :reason, and :stacktrace.
Default metadata
Start metadata includes the requested :model, when supplied, and these provider attributes:
	Adapter	:provider	:operation
	Anthropic	"anthropic"	"chat"
	OpenAI	"openai"	"chat"
	Gemini	"gcp.gemini"	"generate_content"
	OpenRouter	"openrouter"	"chat"
	TypeSafe (Jev)	"typesafe"	"evaluate"

Streaming calls also include stream: true.
Stop metadata retains the start attributes and adds:
	:http_status_code for completed HTTP responses, :error, and :error_type on errors. These describe the HTTP or transport outcome; a provider can report a failure inside a 2xx response while :error is false.
	:response_id, :response_model, :input_tokens, :output_tokens, :cache_read_input_tokens, :cache_write_input_tokens, :reasoning_output_tokens, and :finish_reasons when available. Finish reasons are a list of provider-specific stop reasons or terminal statuses.

For streams, response attributes accumulate from decoded events. Halting before usage arrives leaves token counts unavailable. Built-in extractors do not record request or response bodies.
TypeSafe supports generation only. Its extractor records the response model and reported input/output token usage, but no finish reasons. State, questions, answers, probabilities, and confidence remain in the native request/response bodies and are not recorded in telemetry.
Response IDs and token counts
These fields are metadata in both generation and streaming events:
	:response_id is the provider's message, response, completion, or interaction ID, not an HTTP request ID.
	:input_tokens includes cache reads and cache writes. :cache_read_input_tokens counts input tokens served from cache; :cache_write_input_tokens counts input tokens written to cache.
	:output_tokens includes reasoning/thinking tokens. :reasoning_output_tokens is the separately reported reasoning/thinking portion.

Breakdowns are subsets of the totals: do not add them to the totals again. Anthropic's input total is normalized by adding its cache read and cache creation counts to its uncached input count. Gemini's output total adds its separately reported thought tokens. Other adapters retain the provider's inclusive totals.
	Adapter	Response ID	Cache reads	Cache writes	Reasoning output
	Anthropic	Yes	Yes	Yes	—
	OpenAI	Yes	Yes	Yes	Yes
	Gemini	Yes	Yes	—	Yes
	OpenRouter	Yes	Yes	Yes	Yes
	TypeSafe	—	—	—	—

Fields are emitted only when reported; unsupported, missing, or null breakdowns are omitted, while reported zeros are preserved. Streaming usage snapshots replace earlier counts rather than being summed. Availability can depend on the model and how much of a stream was consumed.
Add custom attributes
Pass :telemetry_metadata when constructing a provider to correlate calls with an application request or conversation.
provider =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    telemetry_metadata: %{
      conversation_id: "conversation_123",
      request_id: "request_456"
    }
  )

ReqAI.generate(provider, model: "gpt-5.4-mini", input: "Summarize this text: ...")
The metadata initializes each call's telemetry and is passed to the extraction callbacks. Use distinct keys for custom attributes; extractors can overwrite existing keys.
Implement custom extraction
Implement ReqAI.Telemetry to derive attributes from requests, responses, or streamed events. All callbacks are optional:
	Callback	Input and timing
	request_metadata/3	The translated request, before :start
	response_metadata/3	A completed non-streaming response, including non-2xx responses; never called for streams or returned transport errors
	event_metadata/4	Each decoded provider event, before event translation and the consumer callback

Each callback receives the current metadata and returns its replacement. Update that map to preserve earlier attributes. Options contain the provider's extra options and the call's :stream flag.
A custom module replaces the provider's extractor. Delegate to the provider to retain its default attributes. This OpenAI example adds the provider's HTTP request ID and counts decoded stream events:
defmodule MyApp.OpenAITelemetry do
  @behaviour ReqAI.Telemetry

  alias ReqAI.Provider.OpenAI

  @impl true
  def request_metadata(metadata, request, opts) do
    OpenAI.request_metadata(metadata, request, opts)
  end

  @impl true
  def response_metadata(metadata, response, opts) do
    metadata = OpenAI.response_metadata(metadata, response, opts)

    case Req.Response.get_header(response, "x-request-id") do
      [id | _] -> Map.put(metadata, :provider_request_id, id)
      [] -> metadata
    end
  end

  @impl true
  def event_metadata(metadata, event, response, opts) do
    metadata
    |> OpenAI.event_metadata(event, response, opts)
    |> Map.update(:event_count, 1, &(&1 + 1))
  end
end

provider =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    telemetry: MyApp.OpenAITelemetry,
    telemetry_metadata: %{feature: :summarizer}
  )
The provider request ID is added to generation stop metadata; the event count is added to streaming stop metadata. Custom extraction changes metadata, not event names or measurements.
Disabling telemetry
Set telemetry: false on the provider to disable both extraction and event emission.
provider = ReqAI.Provider.new(ReqAI.Provider.OpenAI, telemetry: false)

A lightweight Elixir client for AI APIs, built on Req.
Provides consistent generation, streaming, and telemetry with provider-native
requests and responses. Call generate/2 or stream/4 with a provider module
and a provider-native request body. Use ReqAI.Provider.new/2 to configure
a provider explicitly when additional options are needed.
Optional ReqAI.Translator callbacks let applications define their own shared
representations while retaining access to the full Req.Response.

        generate(module, request)

      


        Generates a response.



    


    
      
        stream(module, request, acc, fun)

      


        Streams a response into an accumulator.

          @spec generate(provider :: ReqAI.Provider.t() | module(), request :: term()) ::
  {:ok, Req.Response.t(), term()}
  | {:error, Req.Response.t(), term()}
  | {:error, Exception.t()}


      


Generates a response.
Accepts a configured provider or a provider module. Passing a module calls
ReqAI.Provider.new/2 with no additional options on each invocation, reading
the provider's application-configured HTTP options at that time.
The configured provider builds the request with streaming disabled. The
Req.Response is always returned unchanged as the second element when the
request completes at the HTTP level. The third element is an
application-owned value produced from that response.
For successful responses, the third element is produced by
ReqAI.Translator.response/2; for non-successful responses, it is produced
by ReqAI.Translator.error/2. Both default to response.body when their
callback is not implemented. Transport and decoding failures return
{:error, exception} because no HTTP response or provider-native body is
available.

          @spec stream(
  provider :: ReqAI.Provider.t() | module(),
  request :: term(),
  acc,
  fun :: (term(), Req.Response.t(), acc -> {:cont, acc} | {:halt, acc})
) ::
  {:ok, Req.Response.t(), acc}
  | {:error, Req.Response.t(), acc}
  | {:error, Exception.t(), Req.Response.t() | nil, acc}
when acc: term()


      


Streams a response into an accumulator.
Accepts a configured provider or a provider module. Passing a module calls
ReqAI.Provider.new/2 with no additional options on each invocation, reading
the provider's application-configured HTTP options at that time.
Raises ArgumentError if the provider does not implement
ReqAI.Provider.decode_event/3.
The provider builds the request with streaming enabled. fun receives each
provider-native event, the response as it is being received, and the current
accumulator. It must return {:cont, acc} to continue or {:halt, acc} to
stop consuming the response.
Req handles transport formats such as SSE and NDJSON, then the provider
decodes the resulting values and drops protocol-only events. For the built-in
providers, an SSE event remains a map and its JSON payload is decoded in the
:data field. When a translator implements ReqAI.Translator.event/3, fun
receives its return value. The accompanying response remains the in-progress
Req.Response.
The completed Req.Response remains available. For a successful
stream, the accumulator is the application-owned result of consuming the
translated events. For a non-successful stream, the third element is produced
by ReqAI.Translator.error/2, defaulting to the buffered response body.
Non-successful HTTP responses are not passed to fun. Their streamed data is
instead collected into response.body; JSON error bodies are decoded when
possible.
Returns {:ok, response, acc} for a successful HTTP response,
{:error, response, error} for a non-successful HTTP response, or
{:error, exception, response, acc} for a transport or decoding error.

  


        

      


  

    
ReqAI.Provider behaviour
    



      
Defines the adapter contract and represents a configured AI provider.
Providers build the Req.Request used to execute provider-native request
data. An optional ReqAI.Translator can translate application values at the
provider boundary.
Custom providers
Implement build/3 to support generation. For example, an application-owned
JSON endpoint can use the same calling convention as the built-in providers:
defmodule MyApp.Provider do
  @behaviour ReqAI.Provider

  @impl true
  def build(req, request, _opts) do
    Req.merge(req,
      method: :post,
      url: "https://llm.example.com/generate",
      json: request
    )
  end
end

ReqAI.generate(MyApp.Provider, %{prompt: "Say hello"})
To support streaming, also implement decode_event/3 and use opts[:stream]
in build/3 to select the endpoint's streaming mode. The decoder returns a
list of events; returning [] drops an event. Req handles transport framing
such as SSE, while the provider decodes the native payload.

      


      
        Summary


  
    Types
  


    
      
        t()

      


    





  
    Callbacks
  


    
      
        build(req, request, opts)

      


        Builds the HTTP request for a provider-native request body.



    


    
      
        decode_event(event, response, opts)

      


        Decodes a raw stream event produced by Req (an SSE event map, an NDJSON
line, ...) into zero or more application events.



    





  
    Functions
  


    
      
        new(module, opts \\ [])

      


        Creates a configured provider using module as its adapter.



    





      


      
        Types


        


  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %ReqAI.Provider{
  module: module(),
  opts: keyword(),
  req: Req.Request.t(),
  telemetry: module() | false,
  telemetry_metadata: map(),
  translator: module() | nil
}


      



  


        

      

      
        Callbacks


        


  
    
      
    
    
      build(req, request, opts)



        
          
        

    

  


  

      

          @callback build(req :: Req.Request.t(), request :: map() | keyword(), opts :: keyword()) ::
  Req.Request.t()


      


Builds the HTTP request for a provider-native request body.

  



  
    
      
    
    
      decode_event(event, response, opts)


        (optional)


        
          
        

    

  


  

      

          @callback decode_event(event :: term(), response :: Req.Response.t(), opts :: keyword()) ::
  [term()]


      


Decodes a raw stream event produced by Req (an SSE event map, an NDJSON
line, ...) into zero or more application events.
This callback is optional. Providers must implement it to support ReqAI.stream/4.

  


        

      

      
        Functions


        


    

  
    
      
    
    
      new(module, opts \\ [])



        
          
        

    

  


  

      

          @spec new(module :: module(), opts :: keyword()) :: t()


      


Creates a configured provider using module as its adapter.
If no additional options are needed, pass the module directly to
ReqAI.generate/2 or ReqAI.stream/4. Create and reuse a provider
explicitly to retain its configuration or supply extension options.
module must implement the ReqAI.Provider behaviour.
The :req option contains options passed to Req.new/2. These are
merged with any :req options configured for the adapter under
config :req_ai, :providers, with explicit options taking precedence.
Configuration is read when the provider is created. Only :req is read from
application configuration; extension options must be passed here directly.
After extracting :req, :translator, :telemetry, and
:telemetry_metadata, remaining options are stored on the provider and
passed to build/3 and the configured translator callbacks for each request.
Built-in adapters take body parameters, including :model, from the request
passed to ReqAI.generate/2 or ReqAI.stream/4. They do not merge provider
options into that body. Configure authentication through :req, using Req's
:auth or :headers options as appropriate for the provider.
The optional :translator must implement the ReqAI.Translator behaviour.
The :telemetry option selects a module implementing any of the optional
ReqAI.Telemetry callbacks and defaults to the provider module. Set it to
false to disable telemetry emission. The :telemetry_metadata option
accepts a map that is passed to the telemetry callbacks.

  


        

      


  

    
ReqAI.Telemetry behaviour
    



      
Attribute extraction callbacks for telemetry events.
ReqAI.generate/2 emits [:req_ai, :generate, :start],
[:req_ai, :generate, :stop], and [:req_ai, :generate, :exception] events.
ReqAI.stream/4 emits the same lifecycle events under [:req_ai, :stream].
Attach handlers with :telemetry to observe calls.
The provider module is the default attribute extractor and may implement any
of this module's optional callbacks. Pass telemetry: MyApp.Telemetry to
ReqAI.Provider.new/2 to select another extractor, or telemetry: false to
disable emission. A :telemetry_metadata map adds static tags to events:
ReqAI.Provider.new(ReqAI.Provider.OpenAI,
  telemetry_metadata: %{feature: :summarizer}
)
Metadata uses simple atom keys: :operation, :provider, :model,
:response_id, :response_model, :finish_reasons, :input_tokens, and
:output_tokens. Optional usage breakdowns are :cache_read_input_tokens,
:cache_write_input_tokens, and :reasoning_output_tokens. Input totals
include cache reads/writes; output totals include reasoning. Breakdowns are
subsets of these totals. Missing values are omitted, not recorded as zero.
Extraction coverage varies by provider and request mode; attributes are
included when available. Streaming calls also include stream: true.
Stop metadata includes :http_status_code when an HTTP response is available,
:error, and :error_type on errors.
Stop measurements include :duration. Streaming stop measurements also
include :time_to_first_chunk when a chunk was received, including a
protocol-only event. Both measurements use native time units. Applications
integrating with OpenTelemetry can map metadata to its semantic conventions
in their handlers.
Built-in extractors select operational attributes rather than recording
request or response bodies. Custom extractors and static metadata control
any additional data recorded. Exception events include the standard
:telemetry.span/3 exception metadata, which may contain exception details.

      


      
        Summary


  
    Callbacks
  


    
      
        event_metadata(metadata, event, response, opts)

      


    


    
      
        request_metadata(metadata, request, opts)

      


    


    
      
        response_metadata(metadata, t, opts)

      


    





      


      
        Callbacks


        


  
    
      
    
    
      event_metadata(metadata, event, response, opts)


        (optional)


        
          
        

    

  


  

      

          @callback event_metadata(
  metadata :: map(),
  event :: term(),
  response :: Req.Response.t(),
  opts :: keyword()
) :: map()


      



  



  
    
      
    
    
      request_metadata(metadata, request, opts)


        (optional)


        
          
        

    

  


  

      

          @callback request_metadata(
  metadata :: map(),
  request :: map() | keyword(),
  opts :: keyword()
) :: map()


      



  



  
    
      
    
    
      response_metadata(metadata, t, opts)


        (optional)


        
          
        

    

  


  

      

          @callback response_metadata(metadata :: map(), Req.Response.t(), opts :: keyword()) ::
  map()


      



  


        

      


  

    
ReqAI.Translator behaviour
    



      
Defines translations between application values and provider-native values.
A translator is configured on a ReqAI.Provider and may implement any of the
callbacks in this behaviour. Requests and events are left unchanged when the
corresponding callback is not implemented. Response and error values default
to the provider-native Req.Response.body.
Translators let applications own shared request, response, and event
representations without requiring ReqAI or its provider adapters to define a
universal representation.
Configure a translator with
ReqAI.Provider.new(adapter, translator: MyApp.Translator). Each callback is
optional and receives the configured provider options, including the final
:stream value selected by ReqAI.generate/2 or ReqAI.stream/4.
request/2 must return a provider-native map or keyword list. For completed
HTTP requests, the full Req.Response remains the second tuple element and
the application value is the third. Successful streams use the caller's
accumulator as that value; response/2 is not invoked for streams.
Example
An application can accept a prompt string and translate it into an OpenAI
request while keeping the native response and event formats:
defmodule MyApp.OpenAITranslator do
  @behaviour ReqAI.Translator

  @impl true
  def request(prompt, opts) do
    %{model: Keyword.fetch!(opts, :model), input: prompt}
  end
end

provider =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    translator: MyApp.OpenAITranslator,
    model: "gpt-5.4-mini",
    req: [auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")}]
  )

ReqAI.generate(provider, "Say hello")
Here the translator explicitly reads :model from its options. Built-in
providers do not otherwise merge those options into the request body.

      


      
        Summary


  
    Callbacks
  


    
      
        error(response, opts)

      


        Translates a non-successful HTTP response into an application error.



    


    
      
        event(event, response, opts)

      


        Translates a provider-native streamed event into an application event.



    


    
      
        request(request, opts)

      


        Translates application input into a provider-native request body.



    


    
      
        response(response, opts)

      


        Translates a successful HTTP response into an application response.



    





      


      
        Callbacks


        


  
    
      
    
    
      error(response, opts)


        (optional)


        
          
        

    

  


  

      

          @callback error(response :: Req.Response.t(), opts :: keyword()) :: term()


      


Translates a non-successful HTTP response into an application error.
This callback produces the third element returned by ReqAI.generate/2 or
ReqAI.stream/4 for a non-successful response. For streams, response.body
contains the buffered and, when possible, JSON-decoded error body. It is not
invoked for transport or decoding errors. Its return is an application value;
ReqAI does not reinterpret or raise it.

  



  
    
      
    
    
      event(event, response, opts)


        (optional)


        
          
        

    

  


  

      

          @callback event(event :: term(), response :: Req.Response.t(), opts :: keyword()) ::
  term()


      


Translates a provider-native streamed event into an application event.
response is the HTTP response as it is being received.

  



  
    
      
    
    
      request(request, opts)


        (optional)


        
          
        

    

  


  

      

          @callback request(request :: term(), opts :: keyword()) :: map() | keyword()


      


Translates application input into a provider-native request body.
opts contains the configured provider options and the final :stream value
for the current call.

  



  
    
      
    
    
      response(response, opts)


        (optional)


        
          
        

    

  


  

      

          @callback response(response :: Req.Response.t(), opts :: keyword()) :: term()


      


Translates a successful HTTP response into an application response.
This callback produces the third element returned by ReqAI.generate/2 for
a successful response. It is not invoked for streams or transport errors.

  


        

      


  

    
ReqAI.Provider.Anthropic 
    



      
Provider-native adapter for Anthropic's Messages API.
Sets the anthropic-version: 2023-06-01 header unless explicitly overridden.
Configure API key authentication through Req:
provider =
  ReqAI.Provider.new(ReqAI.Provider.Anthropic,
    req: [headers: [{"x-api-key", System.fetch_env!("ANTHROPIC_API_KEY")}]]
  )

ReqAI.generate(provider, %{
  model: "claude-sonnet-4-6",
  max_tokens: 256,
  messages: [%{role: "user", content: "Say hello"}]
})
Authentication and other :req options can also be set for this provider under
config :req_ai, :providers. Options passed explicitly to ReqAI.Provider.new/2
take precedence over application configuration.

      




  

    
ReqAI.Provider.Gemini 
    



      
Provider-native adapter for Gemini's Interactions API.
Configure API key authentication through Req:
provider =
  ReqAI.Provider.new(ReqAI.Provider.Gemini,
    req: [headers: [{"x-goog-api-key", System.fetch_env!("GEMINI_API_KEY")}]]
  )

ReqAI.generate(provider, %{model: "gemini-3.1-flash-lite", input: "Say hello"})
Authentication and other :req options can also be set for this provider under
config :req_ai, :providers. Options passed explicitly to ReqAI.Provider.new/2
take precedence over application configuration.
This adapter uses Interactions API bodies and events.

      




  

    
ReqAI.Provider.OpenAI 
    



      
Provider-native adapter for the OpenAI Responses API.
Configure bearer authentication through Req:
provider =
  ReqAI.Provider.new(ReqAI.Provider.OpenAI,
    req: [auth: {:bearer, System.fetch_env!("OPENAI_API_KEY")}]
  )

ReqAI.generate(provider, %{model: "gpt-5.4-mini", input: "Say hello"})
Authentication and other :req options can also be set for this provider under
config :req_ai, :providers. Options passed explicitly to ReqAI.Provider.new/2
take precedence over application configuration.
This adapter uses Responses API bodies and events.

      




  

    
ReqAI.Provider.OpenRouter 
    



      
Provider-native adapter for OpenRouter's Chat Completions API.
Configure bearer authentication through Req:
provider =
  ReqAI.Provider.new(ReqAI.Provider.OpenRouter,
    req: [auth: {:bearer, System.fetch_env!("OPENROUTER_API_KEY")}]
  )

ReqAI.generate(provider, %{
  model: "openai/gpt-4",
  messages: [%{role: "user", content: "Say hello"}]
})
Authentication and other :req options can also be set for this provider under
config :req_ai, :providers. Options passed explicitly to ReqAI.Provider.new/2
take precedence over application configuration.
This adapter uses Chat Completions API bodies and events.

      




  

    
ReqAI.Provider.TypeSafe 
    



      
Provider-native adapter for TypeSafe's System One API.
provider =
  ReqAI.Provider.new(ReqAI.Provider.TypeSafe,
    req: [auth: {:bearer, System.fetch_env!("TYPESAFE_API_KEY")}]
  )

ReqAI.generate(provider, %{
  model: "jev-latest",
  state: "Please cancel my subscription.",
  questions: %{
    cancellation: %{
      type: "noul",
      instructions: "Is the customer requesting cancellation?"
    }
  }
})
Streaming is unsupported. ReqAI.stream/4 raises ArgumentError
before making an HTTP request.
Telemetry uses provider: "typesafe" and operation: "evaluate", with model
and input/output token usage when available. No finish reasons are extracted.

